حساس الحرارة والرطوبة DHT11 مع شاشة OLED على ESP32
تجربة تجمع حساسًا وشاشة: يقرأ ESP32 حرارة الغرفة ورطوبتها من DHT11 كل ثانيتين، ويعرضهما بخط كبير على شاشة OLED، ويطبعهما على Serial Monitor فترسمهما في الرسم البياني.
▶ جرّبها على لوحة حقيقيةمجانًا كضيف لدقائق، أو بحساب جامعتك


التوصيل على لوحة المختبر
| القطعة | الطرف |
|---|---|
| DHT11 (Data) | GPIO5 |
| OLED SDA | GPIO22 |
| OLED SCL | GPIO23 |
| عنوان OLED | 0x3C |
الكود الكامل
// تجربة 2: الحرارة والرطوبة DHT11 مع العرض على OLED
// الريليهات: K3 (DHT11) و K5 و K6 (I2C للشاشة)
// المكتبات: DHT sensor library و Adafruit SSD1306 و Adafruit GFX
#include <DHT.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
DHT dht(5, DHT11); // DATA على GPIO5
Adafruit_SSD1306 display(128, 64, &Wire, -1);
void setup() {
Serial.begin(115200);
dht.begin();
Wire.begin(22, 23); // SDA = GPIO22 , SCL = GPIO23 على هذه اللوحة
if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) Serial.println("OLED not found");
display.setRotation(2); // الشاشة مركّبة مقلوبة على اللوحة: ندوّرها 180°
display.setTextColor(SSD1306_WHITE);
}
void loop() {
float t = dht.readTemperature();
float h = dht.readHumidity();
display.clearDisplay();
display.setTextSize(1);
display.setCursor(0, 0);
display.println("DHT11");
if (isnan(t) || isnan(h)) {
Serial.println("Sensor read failed");
display.println("read failed");
} else {
Serial.print(t); Serial.print(" "); Serial.println(h); // للرسم البياني
display.setTextSize(2);
display.setCursor(0, 18); display.print(t, 1); display.println(" C");
display.setCursor(0, 42); display.print(h, 0); display.println(" %");
}
display.display();
delay(2000);
}
المكتبات مثبتة مسبقًا في المختبر.
كيف يعمل
- DHT11 يرسل القراءة رقميًا على سلك واحد بتوقيت خاص، ومكتبة DHT sensor library تتولى ذلك: dht.readTemperature وdht.readHumidity.
- الشاشة على ناقل I2C. على هذه اللوحة SDA هو GPIO22 وSCL هو GPIO23، فنكتب Wire.begin(22, 23) قبل display.begin. ولأن الشاشة مركّبة مقلوبة نكتب setRotation(2).
- مكتبة Adafruit SSD1306 ترسم في ذاكرة، ولا يظهر شيء حتى نستدعي display.display.
أخطاء شائعة وحلولها
- القراءة nan
- ريليه الحساس مفتوح، أو الطرف أو النوع في DHT dht(5, DHT11) غير صحيح. الكود يتحقق بـ isnan، ويقرأ مرة كل ثانيتين كما يحتاج الحساس.
- الشاشة سوداء
- نسيت Wire.begin(22, 23) أو display.display، أو العنوان ليس 0x3C.
- الكتابة مقلوبة
- أضف display.setRotation(2).
حساس المسافة HC-SR04
محرك السيرفو SG90
المقاومة الرقمية DS3502