UniRemoteLab English Deutsch ادخل المختبر

قياس المسافة بحساس HC-SR04 وESP32 مع شاشة OLED

يرسل HC-SR04 نبضة صوتية لا تُسمع ويقيس زمن عودتها بعد ارتدادها عن جسم أمامه. يحسب ESP32 المسافة بالسنتيمتر، ويعرضها رقمًا وشريطًا على شاشة OLED.

▶ جرّبها على لوحة حقيقيةمجانًا كضيف لدقائق، أو بحساب جامعتك
حساس المسافة HC-SR04حساس المسافة HC-SR04

التوصيل على لوحة المختبر

القطعةالطرف
TRIGGPIO4
ECHOGPIO16
OLED SDA / SCLGPIO22 / GPIO23

الكود الكامل

// تجربة 4: حساس المسافة HC-SR04 مع العرض على OLED
// الريليهات: K1 (ECHO) و K2 (TRIG) و K5 و K6 (I2C للشاشة)
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG = 4;
const int ECHO = 16;
Adafruit_SSD1306 display(128, 64, &Wire, -1);

float readCm() {
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  long us = pulseIn(ECHO, HIGH, 30000);   // مهلة 30ms
  return us * 0.0343 / 2;
}

void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  Wire.begin(22, 23);
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) Serial.println("OLED not found");
  display.setRotation(2);                       // الشاشة مركّبة مقلوبة على اللوحة: ندوّرها 180°
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  float cm = readCm();
  Serial.println(cm);
  display.clearDisplay();
  display.setTextSize(1); display.setCursor(0, 0); display.println("Distance");
  display.setTextSize(3); display.setCursor(0, 24);
  if (cm <= 0) display.println("---"); else { display.print(cm, 0); display.setTextSize(2); display.println(" cm"); }
  int bar = constrain((int)(cm * 128 / 100), 0, 128);   // شريط حتى 100 سم
  display.fillRect(0, 58, bar, 6, SSD1306_WHITE);
  display.display();
  delay(300);
}

المكتبات مثبتة مسبقًا في المختبر.

كيف يعمل

  1. نرسل نبضة HIGH مدتها 10 ميكروثانية على TRIG، فيطلق الحساس ثماني نبضات صوتية ويرفع ECHO حتى يعود الصدى.
  2. pulseIn(ECHO, HIGH, 30000) يقيس مدة ECHO بالميكروثانية. الصوت يقطع 0.0343 سم في الميكروثانية، والمسافة ذهاب وإياب، فنقسم على 2.
  3. المهلة 30000 ميكروثانية تمنع الكود من التعلق إن لم يعد صدى، وحينها يرجع pulseIn صفرًا فتعرض الشاشة ---.

أخطاء شائعة وحلولها

القراءة دائمًا 0
ريليه TRIG أو ECHO مفتوح، أو لا يوجد جسم ضمن نحو 4 أمتار.
قراءات تقفز
الأسطح المائلة أو الناعمة تشتت الصوت. خذ متوسط عدة قراءات.
الكود يتجمد
استعمل pulseIn بمهلة كما في الكود.

لا تملك ESP32؟

شغّل هذا الكود الآن على لوحة حقيقية في مختبرنا عن بعد: اكتب، وارفع، وشاهد النتيجة بالكاميرا مباشرة.

ادخل المختبر

دروس أخرى