UniRemoteLab عربي English Zum Labor

Abstand messen mit HC-SR04 und ESP32, Anzeige auf dem OLED

Der HC-SR04 sendet einen unhörbaren Schallimpuls und misst die Zeit, bis sein Echo von einem Gegenstand zurückkommt. Der ESP32 rechnet das in Zentimeter um und zeigt es als Zahl und Balken auf dem OLED.

▶ Auf einem echten Board ausprobierenAls Gast einige Minuten kostenlos, oder mit dem Hochschulkonto
HC-SR04 AbstandHC-SR04 Abstand

Verdrahtung auf dem Laborboard

BauteilPin
TRIGGPIO4
ECHOGPIO16
OLED SDA / SCLGPIO22 / GPIO23

Vollständiger Code

// Versuch 4: Abstandssensor HC-SR04 auf dem OLED
// Relais: K1 (ECHO), K2 (TRIG), K5 und K6 (I2C für das Display)
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

const int TRIG = 4;
const int ECHO = 16;
Adafruit_SSD1306 display(128, 64, &Wire, -1);

float readCm() {
  digitalWrite(TRIG, LOW);  delayMicroseconds(2);
  digitalWrite(TRIG, HIGH); delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  long us = pulseIn(ECHO, HIGH, 30000);   // 30 ms Timeout
  return us * 0.0343 / 2;
}

void setup() {
  Serial.begin(115200);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
  Wire.begin(22, 23);
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) Serial.println("OLED not found");
  display.setRotation(2);                       // das OLED ist auf dieser Platine kopfüber montiert: um 180° drehen
  display.setTextColor(SSD1306_WHITE);
}

void loop() {
  float cm = readCm();
  Serial.println(cm);
  display.clearDisplay();
  display.setTextSize(1); display.setCursor(0, 0); display.println("Distance");
  display.setTextSize(3); display.setCursor(0, 24);
  if (cm <= 0) display.println("---"); else { display.print(cm, 0); display.setTextSize(2); display.println(" cm"); }
  int bar = constrain((int)(cm * 128 / 100), 0, 128);   // Balken bis 100 cm
  display.fillRect(0, 58, bar, 6, SSD1306_WHITE);
  display.display();
  delay(300);
}

Die Bibliotheken sind im Labor bereits installiert.

So funktioniert es

  1. Ein 10-µs-HIGH-Impuls an TRIG lässt den Sensor acht Schallimpulse senden und ECHO auf HIGH setzen, bis das Echo zurückkommt.
  2. pulseIn(ECHO, HIGH, 30000) misst in Mikrosekunden, wie lange ECHO HIGH war. Schall legt 0,0343 cm pro µs zurück, und der Weg geht hin und zurück, also teilen wir durch 2.
  3. Das Timeout von 30000 µs verhindert, dass der Code hängen bleibt, wenn kein Echo kommt; pulseIn() liefert dann 0 und das Display zeigt ---.

Häufige Fehler und Lösungen

Der Wert ist immer 0
Das Relais von TRIG oder ECHO ist offen, oder innerhalb von etwa 4 m ist nichts.
Die Werte springen
Schräge oder weiche Flächen streuen den Schall. Mehrere Messungen mitteln.
Der Code hängt
pulseIn() mit Timeout verwenden, wie im Code.

Kein ESP32 zur Hand?

Diesen Code jetzt auf einem echten Board in unserem Fernlabor ausführen: schreiben, hochladen und das Ergebnis live per Kamera sehen.

Zum Labor

Weitere Tutorials